Описание
Задает или возвращает значение объекта.

Значение
Задаваемое или возвращаемое значение является выражением типа Variant, значение которого принадлежит к типу данных, определенному в свойстве Type объекта.

Замечания
Обычно, свойство Value используют для загрузки и изменения данных в объектах Recordset
. Свойство Value является используемым по умолчанию свойством объектов Field, Parameter и Property. Таким образом, чтобы задать или возвратить значение одного из этих объектов, достаточно сослаться на сам объект без явной ссылки на свойство Value.
Попытка задать значение свойства Value в неподходящем контексте (например, свойство Value объекта Field в семействе Fields объекта TableDef) приведет к перехватываемой ошибке.
В рабочей области ODBCDirect нельзя прочитать или задать значение свойства Value объекта Recordset больше одного раза без обновления текущей записи. Например, чтобы прочитать, а затем задать значение свойства Value, следует сначала прочитать это свойство, затем с помощью инструкции Move 0 обновить текущую запись, а затем записать новое значение.
Десятичные значения, прочитанные из базы данных Microsoft SQL Server, форматируются в экспоненциальной нотации в рабочей области Microsoft Jet, но снова отображаются как обычные десятичные значения в рабочей области ODBCDirect.

Пример
Следующая программа демонстрирует применение свойства Value для объектов Field и Property.

Sub ValueX()

	Dim dbsNorthwind As Database
	Dim rstEmployees As Recordset
	Dim fldLoop As Field
	Dim prpLoop As Property

	Set dbsNorthwind = OpenDatabase("Борей.mdb")
	Set rstEmployees = dbsNorthwind.OpenRecordset("Сотрудники")

	With rstEmployees
		Debug.Print "Значения объектов Field в rstEmployees"
		' Отображает семейство Fields таблицы "Сотрудники".
		For Each fldLoop In .Fields
			Debug.Print "    " & fldLoop.Name & " = ";
			Select Case fldLoop.Type

				Case dbLongBinary
					Debug.Print "[LongBinary]"
				Case dbMemo
					Debug.Print "[Memo]"
				Case Else
					' Так как свойство Value является используемым
					' по умолчанию свойством объекта Field, использование
					' ключевого слова является необязательным.
					Debug.Print fldLoop.Value
			End Select
		Next fldLoop

		Debug.Print "Значения объектов Property в rstEmployees"
		' Отображает семейство Properties объекта Recordset.

		For Each prpLoop In .Properties
			On Error Resume Next
			' Так как свойство Value является используемым 
			' по умолчанию свойством объекта Property, использование
			' ключевого слова является необязательным.
			If prpLoop <> "" Then Debug.Print "    " &  prpLoop.Name & " = " & prpLoop.Value
			On Error GoTo 0
		Next prpLoop
		.Close
	End With
	dbsNorthwind.Close
End Sub