Описание
SourceField — возвращает значение, указывающее имя поля, которое является источником данных объекта Field.
SourceTable — возвращает значение, указывающее имя таблицы, которая является источником данных объекта Field.

Значение
Возвращаемое значение является выражением типа String, указывающим имя поля или таблицы, являющихся источником данных.

Замечания
Использование свойств SourceField и SourceTable зависит от того, какой из объектов содержит семейство Fields, в которое добавлен объект Field, как показано в следующей таблице.

Index		Не поддерживается
QueryDef		Только чтение
Recordset		Только чтение
Relation		Не поддерживается
TableDef		Только чтение

Данные свойства определяют имена исходных поля и таблицы, с которыми связан объект Field. Например, эти свойства можно применить для определения имени источника данных для поля запроса, имя которого не связано с именем поля основной таблицы.
Свойство SourceTable не возвращает осмысленное значение для объекта Field в семействе Fields табличного объекта Recordset.

Пример
Следующая программа демонстрирует применение свойств SourceField и SourceTable путем открытия объекта Recordset, образованного из полей двух таблиц.

Sub SourceFieldX()

	Dim dbsNorthwind As Database
	Dim rstProductCategory As Recordset
	Dim fldLoop As Field
	Dim strSQL As String

	Set dbsNorthwind = OpenDatabase("Борей.mdb")
	' Открывает объект Recordset с помощью инструкции SQL, 
	' в которой используются поля из двух разных таблиц.
	strSQL = "SELECT КодТовара AS Код, " & 	"Марка AS Товар, " & "Типы.КодТипа AS Тип, " & _
		"Категория AS Сорт " & 	"FROM Типы INNER JOIN Товары ON " & _
		"Типы.КодТипа = Товары.КодТипа " & "ORDER BY Марка"
	Set rstProductCategory = dbsNorthwind.OpenRecordset(strSQL)
	Debug.Print "Поле - SourceTable - SourceField"
	' Отображает семейство Fields объекта Recordset, печатая 
	' имя поля, имя исходной таблицы и имя исходного поля.
	For Each fldLoop In rstProductCategory.Fields
		Debug.Print "    " & fldLoop.Name & " - " & 	fldLoop.SourceTable & " - " & fldLoop.SourceField
	Next fldLoop

	rstProductCategory.Close
	dbsNorthwind.Close
End Sub