Описание
Возвращает значение, показывающее, допускается ли обновление данных в поле, которое представляет объект Field.

Значение
Возвращаемое значение имеет тип Boolean и содержит значение True, если данные в поле являются обновляемыми.

Замечания
Данное свойство используют для проверки возможности изменения значения свойства Value объекта Field. Данное свойство всегда имеет значение False для объекта Field, у которого в свойстве Attributes задан тип поля счетчика dbAutoIncrField.
Свойство DataUpdatable применимо к объектам Field, добавленным в семейства Fields объектов QueryDef, Recordset или Relation, но неприменимо для семейств Fields объектов Index или TableDef.

Пример
Следующая программа демонстрирует применение свойства DataUpdatable, используя первое поле из шести различных объектов Recordset. Для выполнения данной процедуры требуется функция DataOutput.

Sub DataUpdatableX()

	Dim dbsNorthwind As Database
	Dim rstNorthwind As Recordset

	Set dbsNorthwind = OpenDatabase("Борей.mdb")

	With dbsNorthwind
		' Открывает и печатает отчет о табличном объекте Recordset.
		Set rstNorthwind = .OpenRecordset("Сотрудники")
		DataOutput rstNorthwind

		' Открывает и печатает отчет о динамическом объекте Recordset.
		Set rstNorthwind = .OpenRecordset("Сотрудники", dbOpenDynaset)
		DataOutput rstNorthwind

		' Открывает и печатает отчет о статическом объекте Recordset.
		Set rstNorthwind = .OpenRecordset("Сотрудники", dbOpenSnapshot)
		DataOutput rstNorthwind

		' Открывает и печатает отчет об объекте Recordset 
		' типа набора записей с последовательным доступом.
		Set rstNorthwind = .OpenRecordset("Сотрудники", dbOpenForwardOnly)
		DataOutput rstNorthwind

		' Открывает и печатает отчет об объекте Recordset,
		' созданном с помощью запроса на выборку.

		Set rstNorthwind = .OpenRecordset("Текущий список товаров")
		DataOutput rstNorthwind

		' Открывает и печатает отчет об объекте Recordset,
		' созданном с помощью запроса на выборку с подсчетом итогов.
		Set rstNorthwind = .OpenRecordset("Суммы заказов")
		DataOutput rstNorthwind

		.Close
	End With

End Sub

Function DataOutput(rstTemp As Recordset)

	With rstTemp
		Debug.Print "Объект Recordset: " & .Name & ", ";
		Select Case .Type
			Case dbOpenTable
				Debug.Print "dbOpenTable"
			Case dbOpenDynaset
				Debug.Print "dbOpenDynaset"
			Case dbOpenSnapshot
				Debug.Print "dbOpenSnapshot"
			Case dbOpenForwardOnly
				Debug.Print "dbOpenForwardOnly"
		End Select
		Debug.Print "    Поле: " & .Fields(0).Name & ", " & "DataUpdatable = " & .Fields(0).DataUpdatable
		Debug.Print
		.Close
	End With

End Function